1# common
2
3find_package(Threads REQUIRED)
4
5llama_add_compile_flags()
6
7# Build info header
8#
9
10if(EXISTS "${PROJECT_SOURCE_DIR}/.git")
11 set(GIT_DIR "${PROJECT_SOURCE_DIR}/.git")
12
13 # Is git submodule
14 if(NOT IS_DIRECTORY "${GIT_DIR}")
15 file(READ ${GIT_DIR} REAL_GIT_DIR_LINK)
16 string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" REAL_GIT_DIR ${REAL_GIT_DIR_LINK})
17 string(FIND "${REAL_GIT_DIR}" "/" SLASH_POS)
18 if (SLASH_POS EQUAL 0)
19 set(GIT_DIR "${REAL_GIT_DIR}")
20 else()
21 set(GIT_DIR "${PROJECT_SOURCE_DIR}/${REAL_GIT_DIR}")
22 endif()
23 endif()
24
25 if(EXISTS "${GIT_DIR}/index")
26 # For build-info.cpp below
27 set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS "${GIT_DIR}/index")
28 else()
29 message(WARNING "Git index not found in git repository.")
30 endif()
31else()
32 message(WARNING "Git repository not found; to enable automatic generation of build info, make sure Git is installed and the project is a Git repository.")
33endif()
34
35set(TEMPLATE_FILE "${CMAKE_CURRENT_SOURCE_DIR}/build-info.cpp.in")
36set(OUTPUT_FILE "${CMAKE_CURRENT_BINARY_DIR}/build-info.cpp")
37configure_file(${TEMPLATE_FILE} ${OUTPUT_FILE})
38
39set(TARGET build_info)
40add_library(${TARGET} OBJECT ${OUTPUT_FILE})
41if (BUILD_SHARED_LIBS)
42 set_target_properties(${TARGET} PROPERTIES POSITION_INDEPENDENT_CODE ON)
43endif()
44
45set(TARGET common)
46
47add_library(${TARGET} STATIC
48 arg.cpp
49 arg.h
50 base64.hpp
51 chat-parser.cpp
52 chat-parser.h
53 chat-parser-xml-toolcall.h
54 chat-parser-xml-toolcall.cpp
55 chat-peg-parser.cpp
56 chat-peg-parser.h
57 chat.cpp
58 chat.h
59 common.cpp
60 common.h
61 console.cpp
62 console.h
63 debug.cpp
64 debug.h
65 download.cpp
66 download.h
67 http.h
68 json-partial.cpp
69 json-partial.h
70 json-schema-to-grammar.cpp
71 llguidance.cpp
72 log.cpp
73 log.h
74 ngram-cache.cpp
75 ngram-cache.h
76 ngram-map.cpp
77 ngram-map.h
78 ngram-mod.cpp
79 ngram-mod.h
80 peg-parser.cpp
81 peg-parser.h
82 preset.cpp
83 preset.h
84 regex-partial.cpp
85 regex-partial.h
86 sampling.cpp
87 sampling.h
88 speculative.cpp
89 speculative.h
90 unicode.cpp
91 unicode.h
92 jinja/lexer.cpp
93 jinja/lexer.h
94 jinja/parser.cpp
95 jinja/parser.h
96 jinja/runtime.cpp
97 jinja/runtime.h
98 jinja/value.cpp
99 jinja/value.h
100 jinja/string.cpp
101 jinja/string.h
102 jinja/caps.cpp
103 jinja/caps.h
104 )
105
106target_include_directories(${TARGET} PUBLIC . ../vendor)
107target_compile_features (${TARGET} PUBLIC cxx_std_17)
108
109if (BUILD_SHARED_LIBS)
110 set_target_properties(${TARGET} PROPERTIES POSITION_INDEPENDENT_CODE ON)
111endif()
112
113# TODO: use list(APPEND LLAMA_COMMON_EXTRA_LIBS ...)
114set(LLAMA_COMMON_EXTRA_LIBS build_info)
115
116if (LLAMA_HTTPLIB)
117 target_compile_definitions(${TARGET} PUBLIC LLAMA_USE_HTTPLIB)
118 set(LLAMA_COMMON_EXTRA_LIBS ${LLAMA_COMMON_EXTRA_LIBS} cpp-httplib)
119endif()
120
121if (LLAMA_LLGUIDANCE)
122 include(ExternalProject)
123 set(LLGUIDANCE_SRC ${CMAKE_BINARY_DIR}/llguidance/source)
124 set(LLGUIDANCE_PATH ${LLGUIDANCE_SRC}/target/release)
125
126 # Set the correct library file extension based on platform
127 if (WIN32)
128 set(LLGUIDANCE_LIB_NAME "llguidance.lib")
129 # Add Windows-specific libraries
130 set(LLGUIDANCE_PLATFORM_LIBS
131 ws2_32 # Windows Sockets API
132 userenv # For GetUserProfileDirectoryW
133 ntdll # For NT functions
134 bcrypt # For BCryptGenRandom
135 )
136 else()
137 set(LLGUIDANCE_LIB_NAME "libllguidance.a")
138 set(LLGUIDANCE_PLATFORM_LIBS "")
139 endif()
140
141 ExternalProject_Add(llguidance_ext
142 GIT_REPOSITORY https://github.com/guidance-ai/llguidance
143 # v1.0.1:
144 GIT_TAG d795912fedc7d393de740177ea9ea761e7905774
145 PREFIX ${CMAKE_BINARY_DIR}/llguidance
146 SOURCE_DIR ${LLGUIDANCE_SRC}
147 BUILD_IN_SOURCE TRUE
148 CONFIGURE_COMMAND ""
149 BUILD_COMMAND cargo build --release --package llguidance
150 INSTALL_COMMAND ""
151 BUILD_BYPRODUCTS ${LLGUIDANCE_PATH}/${LLGUIDANCE_LIB_NAME} ${LLGUIDANCE_PATH}/llguidance.h
152 UPDATE_COMMAND ""
153 )
154 target_compile_definitions(${TARGET} PUBLIC LLAMA_USE_LLGUIDANCE)
155
156 add_library(llguidance STATIC IMPORTED)
157 set_target_properties(llguidance PROPERTIES IMPORTED_LOCATION ${LLGUIDANCE_PATH}/${LLGUIDANCE_LIB_NAME})
158 add_dependencies(llguidance llguidance_ext)
159
160 target_include_directories(${TARGET} PRIVATE ${LLGUIDANCE_PATH})
161 # Add platform libraries to the main target
162 set(LLAMA_COMMON_EXTRA_LIBS ${LLAMA_COMMON_EXTRA_LIBS} llguidance ${LLGUIDANCE_PLATFORM_LIBS})
163endif ()
164
165target_link_libraries(${TARGET} PRIVATE ${LLAMA_COMMON_EXTRA_LIBS} PUBLIC llama Threads::Threads)