1@PACKAGE_INIT@
2
3@GGML_VARIABLES_EXPANDED@
4
5# Find all dependencies before creating any target.
6include(CMakeFindDependencyMacro)
7find_dependency(Threads)
8if (NOT GGML_SHARED_LIB)
9 set(GGML_CPU_INTERFACE_LINK_LIBRARIES "")
10 set(GGML_CPU_INTERFACE_LINK_OPTIONS "")
11
12 if (APPLE AND GGML_ACCELERATE)
13 find_library(ACCELERATE_FRAMEWORK Accelerate)
14 if(NOT ACCELERATE_FRAMEWORK)
15 set(${CMAKE_FIND_PACKAGE_NAME}_FOUND 0)
16 return()
17 endif()
18 list(APPEND GGML_CPU_INTERFACE_LINK_LIBRARIES ${ACCELERATE_FRAMEWORK})
19 endif()
20
21 if (GGML_OPENMP_ENABLED)
22 find_dependency(OpenMP)
23 list(APPEND GGML_CPU_INTERFACE_LINK_LIBRARIES OpenMP::OpenMP_C OpenMP::OpenMP_CXX)
24 endif()
25
26 if (GGML_CPU_HBM)
27 find_library(memkind memkind)
28 if(NOT memkind)
29 set(${CMAKE_FIND_PACKAGE_NAME}_FOUND 0)
30 return()
31 endif()
32 list(APPEND GGML_CPU_INTERFACE_LINK_LIBRARIES memkind)
33 endif()
34
35 if (GGML_BLAS)
36 find_dependency(BLAS)
37 list(APPEND GGML_BLAS_INTERFACE_LINK_LIBRARIES ${BLAS_LIBRARIES})
38 list(APPEND GGML_BLAS_INTERFACE_LINK_OPTIONS ${BLAS_LINKER_FLAGS})
39 endif()
40
41 if (GGML_CUDA)
42 set(GGML_CUDA_INTERFACE_LINK_LIBRARIES "")
43 find_dependency(CUDAToolkit)
44 if (GGML_STATIC)
45 list(APPEND GGML_CUDA_INTERFACE_LINK_LIBRARIES $<LINK_ONLY:CUDA::cudart_static>)
46 if (WIN32)
47 list(APPEND GGML_CUDA_INTERFACE_LINK_LIBRARIES $<LINK_ONLY:CUDA::cublas> $<LINK_ONLY:CUDA::cublasLt>)
48 else()
49 list(APPEND GGML_CUDA_INTERFACE_LINK_LIBRARIES $<LINK_ONLY:CUDA::cublas_static> $<LINK_ONLY:CUDA::cublasLt_static>)
50 endif()
51 endif()
52 if (NOT GGML_CUDA_NO_VMM)
53 list(APPEND GGML_CUDA_INTERFACE_LINK_LIBRARIES $<LINK_ONLY:CUDA::cuda_driver>)
54 endif()
55 endif()
56
57 if (GGML_METAL)
58 find_library(FOUNDATION_LIBRARY Foundation)
59 find_library(METAL_FRAMEWORK Metal)
60 find_library(METALKIT_FRAMEWORK MetalKit)
61 if(NOT FOUNDATION_LIBRARY OR NOT METAL_FRAMEWORK OR NOT METALKIT_FRAMEWORK)
62 set(${CMAKE_FIND_PACKAGE_NAME}_FOUND 0)
63 return()
64 endif()
65 set(GGML_METAL_INTERFACE_LINK_LIBRARIES
66 ${FOUNDATION_LIBRARY} ${METAL_FRAMEWORK} ${METALKIT_FRAMEWORK})
67 endif()
68
69 if (GGML_OPENCL)
70 find_dependency(OpenCL)
71 set(GGML_OPENCL_INTERFACE_LINK_LIBRARIES $<LINK_ONLY:OpenCL::OpenCL>)
72 endif()
73
74 if (GGML_VULKAN)
75 find_dependency(Vulkan)
76 set(GGML_VULKAN_INTERFACE_LINK_LIBRARIES $<LINK_ONLY:Vulkan::Vulkan>)
77 endif()
78
79 if (GGML_HIP)
80 find_dependency(hip)
81 find_dependency(hipblas)
82 find_dependency(rocblas)
83 set(GGML_HIP_INTERFACE_LINK_LIBRARIES hip::host roc::rocblas roc::hipblas)
84 endif()
85
86 if (GGML_SYCL)
87 set(GGML_SYCL_INTERFACE_LINK_LIBRARIES "")
88 find_package(DNNL)
89 if (${DNNL_FOUND} AND GGML_SYCL_TARGET STREQUAL "INTEL")
90 list(APPEND GGML_SYCL_INTERFACE_LINK_LIBRARIES DNNL::dnnl)
91 endif()
92 if (WIN32)
93 find_dependency(IntelSYCL)
94 find_dependency(MKL)
95 list(APPEND GGML_SYCL_INTERFACE_LINK_LIBRARIES IntelSYCL::SYCL_CXX MKL::MKL MKL::MKL_SYCL)
96 endif()
97 endif()
98endif()
99
100set_and_check(GGML_INCLUDE_DIR "@PACKAGE_GGML_INCLUDE_INSTALL_DIR@")
101set_and_check(GGML_LIB_DIR "@PACKAGE_GGML_LIB_INSTALL_DIR@")
102#set_and_check(GGML_BIN_DIR "@PACKAGE_GGML_BIN_INSTALL_DIR@")
103
104if(NOT TARGET ggml::ggml)
105 find_package(Threads REQUIRED)
106
107 find_library(GGML_LIBRARY ggml
108 REQUIRED
109 HINTS ${GGML_LIB_DIR}
110 NO_CMAKE_FIND_ROOT_PATH)
111
112 add_library(ggml::ggml UNKNOWN IMPORTED)
113 set_target_properties(ggml::ggml
114 PROPERTIES
115 IMPORTED_LOCATION "${GGML_LIBRARY}")
116
117 find_library(GGML_BASE_LIBRARY ggml-base
118 REQUIRED
119 HINTS ${GGML_LIB_DIR}
120 NO_CMAKE_FIND_ROOT_PATH)
121
122 add_library(ggml::ggml-base UNKNOWN IMPORTED)
123 set_target_properties(ggml::ggml-base
124 PROPERTIES
125 IMPORTED_LOCATION "${GGML_BASE_LIBRARY}")
126
127 set(_ggml_all_targets "")
128 if (NOT GGML_BACKEND_DL)
129 foreach(_ggml_backend ${GGML_AVAILABLE_BACKENDS})
130 string(REPLACE "-" "_" _ggml_backend_pfx "${_ggml_backend}")
131 string(TOUPPER "${_ggml_backend_pfx}" _ggml_backend_pfx)
132
133 find_library(${_ggml_backend_pfx}_LIBRARY ${_ggml_backend}
134 REQUIRED
135 HINTS ${GGML_LIB_DIR}
136 NO_CMAKE_FIND_ROOT_PATH)
137
138 message(STATUS "Found ${${_ggml_backend_pfx}_LIBRARY}")
139
140 add_library(ggml::${_ggml_backend} UNKNOWN IMPORTED)
141 set_target_properties(ggml::${_ggml_backend}
142 PROPERTIES
143 INTERFACE_INCLUDE_DIRECTORIES "${GGML_INCLUDE_DIR}"
144 IMPORTED_LINK_INTERFACE_LANGUAGES "CXX"
145 IMPORTED_LOCATION "${${_ggml_backend_pfx}_LIBRARY}"
146 INTERFACE_COMPILE_FEATURES c_std_90
147 POSITION_INDEPENDENT_CODE ON)
148
149 string(REGEX MATCH "^ggml-cpu" is_cpu_variant "${_ggml_backend}")
150 if(is_cpu_variant)
151 list(APPEND GGML_CPU_INTERFACE_LINK_LIBRARIES "ggml::ggml-base")
152 set_target_properties(ggml::${_ggml_backend}
153 PROPERTIES
154 INTERFACE_LINK_LIBRARIES "${GGML_CPU_INTERFACE_LINK_LIBRARIES}")
155
156 if(GGML_CPU_INTERFACE_LINK_OPTIONS)
157 set_target_properties(ggml::${_ggml_backend}
158 PROPERTIES
159 INTERFACE_LINK_OPTIONS "${GGML_CPU_INTERFACE_LINK_OPTIONS}")
160 endif()
161
162 else()
163 list(APPEND ${_ggml_backend_pfx}_INTERFACE_LINK_LIBRARIES "ggml::ggml-base")
164 set_target_properties(ggml::${_ggml_backend}
165 PROPERTIES
166 INTERFACE_LINK_LIBRARIES "${${_ggml_backend_pfx}_INTERFACE_LINK_LIBRARIES}")
167
168 if(${_ggml_backend_pfx}_INTERFACE_LINK_OPTIONS)
169 set_target_properties(ggml::${_ggml_backend}
170 PROPERTIES
171 INTERFACE_LINK_OPTIONS "${${_ggml_backend_pfx}_INTERFACE_LINK_OPTIONS}")
172 endif()
173 endif()
174
175 list(APPEND _ggml_all_targets ggml::${_ggml_backend})
176 endforeach()
177 endif()
178
179 list(APPEND GGML_INTERFACE_LINK_LIBRARIES ggml::ggml-base "${_ggml_all_targets}")
180 set_target_properties(ggml::ggml
181 PROPERTIES
182 INTERFACE_LINK_LIBRARIES "${GGML_INTERFACE_LINK_LIBRARIES}")
183
184 add_library(ggml::all INTERFACE IMPORTED)
185 set_target_properties(ggml::all
186 PROPERTIES
187 INTERFACE_LINK_LIBRARIES "${_ggml_all_targets}")
188
189endif()
190
191check_required_components(ggml)