1cmake_minimum_required(VERSION 3.19)
2cmake_policy(SET CMP0114 NEW)
3cmake_policy(SET CMP0116 NEW)
4if (POLICY CMP0147)
5 # Parallel build custom build steps
6 cmake_policy(SET CMP0147 NEW)
7endif()
8
9find_package(Vulkan COMPONENTS glslc REQUIRED)
10
11if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
12 # Parallel build object files
13 add_definitions(/MP)
14endif()
15
16function(detect_host_compiler)
17 if (CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows")
18 find_program(HOST_C_COMPILER NAMES cl gcc clang NO_CMAKE_FIND_ROOT_PATH)
19 find_program(HOST_CXX_COMPILER NAMES cl g++ clang++ NO_CMAKE_FIND_ROOT_PATH)
20 else()
21 find_program(HOST_C_COMPILER NAMES gcc clang NO_CMAKE_FIND_ROOT_PATH)
22 find_program(HOST_CXX_COMPILER NAMES g++ clang++ NO_CMAKE_FIND_ROOT_PATH)
23 endif()
24 set(HOST_C_COMPILER "${HOST_C_COMPILER}" PARENT_SCOPE)
25 set(HOST_CXX_COMPILER "${HOST_CXX_COMPILER}" PARENT_SCOPE)
26endfunction()
27
28# Function to test shader extension support
29# Parameters:
30# EXTENSION_NAME - Name of the extension to test (e.g., "GL_EXT_integer_dot_product")
31# TEST_SHADER_FILE - Path to the test shader file
32# RESULT_VARIABLE - Name of the variable to set (ON/OFF) based on test result
33function(test_shader_extension_support EXTENSION_NAME TEST_SHADER_FILE RESULT_VARIABLE)
34 execute_process(
35 COMMAND ${Vulkan_GLSLC_EXECUTABLE} -o - -fshader-stage=compute --target-env=vulkan1.3 "${TEST_SHADER_FILE}"
36 OUTPUT_VARIABLE glslc_output
37 ERROR_VARIABLE glslc_error
38 )
39
40 if (${glslc_error} MATCHES ".*extension not supported: ${EXTENSION_NAME}.*")
41 message(STATUS "${EXTENSION_NAME} not supported by glslc")
42 set(${RESULT_VARIABLE} OFF PARENT_SCOPE)
43 else()
44 message(STATUS "${EXTENSION_NAME} supported by glslc")
45 set(${RESULT_VARIABLE} ON PARENT_SCOPE)
46 add_compile_definitions(${RESULT_VARIABLE})
47
48 # Ensure the extension support is forwarded to vulkan-shaders-gen
49 list(APPEND VULKAN_SHADER_GEN_CMAKE_ARGS -D${RESULT_VARIABLE}=ON)
50 set(VULKAN_SHADER_GEN_CMAKE_ARGS "${VULKAN_SHADER_GEN_CMAKE_ARGS}" PARENT_SCOPE)
51 endif()
52endfunction()
53
54if (Vulkan_FOUND)
55 message(STATUS "Vulkan found")
56
57 ggml_add_backend_library(ggml-vulkan
58 ggml-vulkan.cpp
59 ../../include/ggml-vulkan.h
60 )
61
62 set(VULKAN_SHADER_GEN_CMAKE_ARGS "")
63
64 # Test all shader extensions
65 test_shader_extension_support(
66 "GL_KHR_cooperative_matrix"
67 "${CMAKE_CURRENT_SOURCE_DIR}/vulkan-shaders/feature-tests/coopmat.comp"
68 "GGML_VULKAN_COOPMAT_GLSLC_SUPPORT"
69 )
70
71 test_shader_extension_support(
72 "GL_NV_cooperative_matrix2"
73 "${CMAKE_CURRENT_SOURCE_DIR}/vulkan-shaders/feature-tests/coopmat2.comp"
74 "GGML_VULKAN_COOPMAT2_GLSLC_SUPPORT"
75 )
76
77 test_shader_extension_support(
78 "GL_EXT_integer_dot_product"
79 "${CMAKE_CURRENT_SOURCE_DIR}/vulkan-shaders/feature-tests/integer_dot.comp"
80 "GGML_VULKAN_INTEGER_DOT_GLSLC_SUPPORT"
81 )
82
83 test_shader_extension_support(
84 "GL_EXT_bfloat16"
85 "${CMAKE_CURRENT_SOURCE_DIR}/vulkan-shaders/feature-tests/bfloat16.comp"
86 "GGML_VULKAN_BFLOAT16_GLSLC_SUPPORT"
87 )
88
89 target_link_libraries(ggml-vulkan PRIVATE Vulkan::Vulkan)
90 target_include_directories(ggml-vulkan PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
91
92 # Workaround to the "can't dereference invalidated vector iterator" bug in clang-cl debug build
93 # Posssibly relevant: https://stackoverflow.com/questions/74748276/visual-studio-no-displays-the-correct-length-of-stdvector
94 if (MSVC AND CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
95 add_compile_definitions(_ITERATOR_DEBUG_LEVEL=0)
96 endif()
97
98 if (GGML_VULKAN_CHECK_RESULTS)
99 add_compile_definitions(GGML_VULKAN_CHECK_RESULTS)
100 endif()
101
102 if (GGML_VULKAN_DEBUG)
103 add_compile_definitions(GGML_VULKAN_DEBUG)
104 endif()
105
106 if (GGML_VULKAN_MEMORY_DEBUG)
107 add_compile_definitions(GGML_VULKAN_MEMORY_DEBUG)
108 endif()
109
110 if (GGML_VULKAN_SHADER_DEBUG_INFO)
111 add_compile_definitions(GGML_VULKAN_SHADER_DEBUG_INFO)
112 list(APPEND VULKAN_SHADER_GEN_CMAKE_ARGS -DGGML_VULKAN_SHADER_DEBUG_INFO=ON)
113 endif()
114
115 if (GGML_VULKAN_VALIDATE)
116 add_compile_definitions(GGML_VULKAN_VALIDATE)
117 endif()
118
119 if (GGML_VULKAN_RUN_TESTS)
120 add_compile_definitions(GGML_VULKAN_RUN_TESTS)
121 endif()
122
123 # Set up toolchain for host compilation whether cross-compiling or not
124 if (CMAKE_CROSSCOMPILING)
125 if (GGML_VULKAN_SHADERS_GEN_TOOLCHAIN)
126 set(HOST_CMAKE_TOOLCHAIN_FILE ${GGML_VULKAN_SHADERS_GEN_TOOLCHAIN})
127 else()
128 detect_host_compiler()
129 if (NOT HOST_C_COMPILER OR NOT HOST_CXX_COMPILER)
130 message(FATAL_ERROR "Host compiler not found")
131 else()
132 message(STATUS "Host compiler: ${HOST_C_COMPILER} ${HOST_CXX_COMPILER}")
133 endif()
134 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/host-toolchain.cmake.in ${CMAKE_BINARY_DIR}/host-toolchain.cmake @ONLY)
135 set(HOST_CMAKE_TOOLCHAIN_FILE ${CMAKE_BINARY_DIR}/host-toolchain.cmake)
136 endif()
137 else()
138 # For non-cross-compiling, use empty toolchain (use host compiler)
139 set(HOST_CMAKE_TOOLCHAIN_FILE "")
140 endif()
141
142 include(ExternalProject)
143
144 if (CMAKE_CROSSCOMPILING)
145 list(APPEND VULKAN_SHADER_GEN_CMAKE_ARGS -DCMAKE_TOOLCHAIN_FILE=${HOST_CMAKE_TOOLCHAIN_FILE})
146 message(STATUS "vulkan-shaders-gen toolchain file: ${HOST_CMAKE_TOOLCHAIN_FILE}")
147 endif()
148
149 ExternalProject_Add(
150 vulkan-shaders-gen
151 SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/vulkan-shaders
152 CMAKE_ARGS -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_DIR}/$<CONFIG>
153 -DCMAKE_INSTALL_BINDIR=.
154 -DCMAKE_BUILD_TYPE=$<CONFIG>
155 ${VULKAN_SHADER_GEN_CMAKE_ARGS}
156
157 BUILD_COMMAND ${CMAKE_COMMAND} --build . --config $<CONFIG>
158 BUILD_ALWAYS TRUE
159
160 # NOTE: When DESTDIR is set using Makefile generators and
161 # "make install" triggers the build step, vulkan-shaders-gen
162 # would be installed into the DESTDIR prefix, so it is unset
163 # to ensure that does not happen.
164
165 INSTALL_COMMAND ${CMAKE_COMMAND} -E env --unset=DESTDIR
166 ${CMAKE_COMMAND} --install . --config $<CONFIG>
167 )
168
169 set (_ggml_vk_host_suffix $<IF:$<STREQUAL:${CMAKE_HOST_SYSTEM_NAME},Windows>,.exe,>)
170 set (_ggml_vk_genshaders_dir "${CMAKE_BINARY_DIR}/$<CONFIG>")
171 set (_ggml_vk_genshaders_cmd "${_ggml_vk_genshaders_dir}/vulkan-shaders-gen${_ggml_vk_host_suffix}")
172 set (_ggml_vk_header "${CMAKE_CURRENT_BINARY_DIR}/ggml-vulkan-shaders.hpp")
173 set (_ggml_vk_input_dir "${CMAKE_CURRENT_SOURCE_DIR}/vulkan-shaders")
174 set (_ggml_vk_output_dir "${CMAKE_CURRENT_BINARY_DIR}/vulkan-shaders.spv")
175
176 file(GLOB _ggml_vk_shader_files CONFIGURE_DEPENDS "${_ggml_vk_input_dir}/*.comp")
177
178 # Because external projects do not provide source-level tracking,
179 # the vulkan-shaders-gen sources need to be explicitly added to
180 # ensure that changes will cascade into shader re-generation.
181
182 file(GLOB _ggml_vk_shaders_gen_sources
183 CONFIGURE_DEPENDS "${_ggml_vk_input_dir}/*.cpp"
184 "${_ggml_vk_input_dir}/*.h")
185
186 add_custom_command(
187 OUTPUT ${_ggml_vk_header}
188 COMMAND ${_ggml_vk_genshaders_cmd}
189 --output-dir ${_ggml_vk_output_dir}
190 --target-hpp ${_ggml_vk_header}
191 DEPENDS ${_ggml_vk_shaders_gen_sources}
192 vulkan-shaders-gen
193 COMMENT "Generate vulkan shaders header"
194 )
195 target_sources(ggml-vulkan PRIVATE ${_ggml_vk_header})
196
197 foreach (file_full ${_ggml_vk_shader_files})
198 get_filename_component(file ${file_full} NAME)
199 set (_ggml_vk_target_cpp "${CMAKE_CURRENT_BINARY_DIR}/${file}.cpp")
200
201 add_custom_command(
202 OUTPUT ${_ggml_vk_target_cpp}
203 DEPFILE ${_ggml_vk_target_cpp}.d
204 COMMAND ${_ggml_vk_genshaders_cmd}
205 --glslc ${Vulkan_GLSLC_EXECUTABLE}
206 --source ${file_full}
207 --output-dir ${_ggml_vk_output_dir}
208 --target-hpp ${_ggml_vk_header}
209 --target-cpp ${_ggml_vk_target_cpp}
210 DEPENDS ${file_full}
211 ${_ggml_vk_shaders_gen_sources}
212 vulkan-shaders-gen
213 COMMENT "Generate vulkan shaders for ${file}"
214 )
215 target_sources(ggml-vulkan PRIVATE ${_ggml_vk_target_cpp})
216 endforeach()
217
218else()
219 message(WARNING "Vulkan not found")
220endif()