1#version 450
 2
 3#include "dequant_head.glsl"
 4
 5layout(local_size_x = 256, local_size_y = 1, local_size_z = 1) in;
 6
 7layout (binding = 0) readonly buffer A {block_iq3_xxs data_a[];};
 8layout (binding = 1) writeonly buffer D {D_TYPE data_b[];};
 9
10void main() {
11    // Each thread handles 1 scale block (32 values)
12    // 8 threads handle 1 superblock
13    const uint ib = gl_WorkGroupID.x * 32 + gl_LocalInvocationID.x / 8;
14
15    init_iq_shmem(gl_WorkGroupSize);
16
17    if (ib >= p.nel / 256) {
18        return;
19    }
20
21    const uint is = gl_LocalInvocationID.x % 8;
22    const uint b_idx = 256 * ib + 32 * is;
23    const uint s_idx = QUANT_K / 4 + 4 * is;
24
25    const float d = float(data_a[ib].d);
26    uint signscale = pack32(u8vec4(
27        data_a[ib].qs[s_idx + 0],
28        data_a[ib].qs[s_idx + 1],
29        data_a[ib].qs[s_idx + 2],
30        data_a[ib].qs[s_idx + 3]
31    ));
32    const float db = d * (0.5 + (signscale >> 28)) * 0.5;
33
34    [[unroll]] for (uint l = 0; l < 4; ++l) {
35        const uint sign7 = bitfieldExtract(signscale, 7 * int(l), 7);
36        // Restore parity bit.
37        const uint sign8 = sign7 | (bitCount(sign7) << 7);
38        const uint qs0 = data_a[ib].qs[8 * is + 2 * l];
39        const uint qs1 = data_a[ib].qs[8 * is + 2 * l + 1];
40        const u8vec4 grid0 = unpack8(iq3xxs_grid[qs0]);
41        const u8vec4 grid1 = unpack8(iq3xxs_grid[qs1]);
42        data_b[b_idx + 8 * l + 0] = D_TYPE(db * grid0.x * ((sign8 & 1) != 0 ? -1.0 : 1.0));
43        data_b[b_idx + 8 * l + 1] = D_TYPE(db * grid0.y * ((sign8 & 2) != 0 ? -1.0 : 1.0));
44        data_b[b_idx + 8 * l + 2] = D_TYPE(db * grid0.z * ((sign8 & 4) != 0 ? -1.0 : 1.0));
45        data_b[b_idx + 8 * l + 3] = D_TYPE(db * grid0.w * ((sign8 & 8) != 0 ? -1.0 : 1.0));
46        data_b[b_idx + 8 * l + 4] = D_TYPE(db * grid1.x * ((sign8 & 16) != 0 ? -1.0 : 1.0));
47        data_b[b_idx + 8 * l + 5] = D_TYPE(db * grid1.y * ((sign8 & 32) != 0 ? -1.0 : 1.0));
48        data_b[b_idx + 8 * l + 6] = D_TYPE(db * grid1.z * ((sign8 & 64) != 0 ? -1.0 : 1.0));
49        data_b[b_idx + 8 * l + 7] = D_TYPE(db * grid1.w * ((sign8 & 128) != 0 ? -1.0 : 1.0));
50    }
51}