1#version 450
 2#extension GL_EXT_shader_explicit_arithmetic_types_int32 : require
 3
 4#include "mul_mat_vec_base.glsl"
 5
 6layout(local_size_x_id = 0, local_size_y = 1, local_size_z = 1) in;
 7
 8FLOAT_TYPE temp[NUM_COLS][NUM_ROWS];
 9
10void calc_superblock(const uint a_offset, const uint b_offset, const uint itid, const uint i, const uint num_blocks_per_row, const uint first_row, const uint num_rows) {
11    const uint y_idx = i * QUANT_K + 16 * itid;
12    const uint ib32 = itid / 2; // 0..7
13
14    uint ibi = a_offset + first_row * num_blocks_per_row + i;
15    [[unroll]] for (uint n = 0; n < num_rows; ++n) {
16        const float d = float(data_a[ibi].d);
17        const uint signscale = pack32(u16vec2(
18            data_a_packed16[ibi].qs[4 * ib32 + 2],
19            data_a_packed16[ibi].qs[4 * ib32 + 3]));
20        const float db = d * 0.25 * (0.5 + (signscale >> 28));
21        [[unroll]] for (uint l = 0; l < 2; ++l) {
22            const uint qs = data_a[ibi].qs[8 * ib32 + 2 * (itid & 1) + l];
23            const uint sign = bitfieldExtract(signscale, 7 * int(2 * (itid & 1) + l), 7);
24            const uint sign7 = bitCount(sign);
25            const vec4 grid0 = vec4(unpack8(iq2xxs_grid[qs].x));
26            const vec4 grid1 = vec4(unpack8(iq2xxs_grid[qs].y));
27
28            [[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
29                const vec4 b0 = vec4(data_b_v4[(j*p.batch_stride_b + b_offset + y_idx) / 4 + 2*l + 0]);
30                const vec4 b4 = vec4(data_b_v4[(j*p.batch_stride_b + b_offset + y_idx) / 4 + 2*l + 1]);
31
32                FLOAT_TYPE sum =
33                      fma(FLOAT_TYPE(b0.x), FLOAT_TYPE((sign &   1) != 0 ? -grid0.x : grid0.x),
34                      fma(FLOAT_TYPE(b0.y), FLOAT_TYPE((sign &   2) != 0 ? -grid0.y : grid0.y),
35                      fma(FLOAT_TYPE(b0.z), FLOAT_TYPE((sign &   4) != 0 ? -grid0.z : grid0.z),
36                      fma(FLOAT_TYPE(b0.w), FLOAT_TYPE((sign &   8) != 0 ? -grid0.w : grid0.w),
37                      fma(FLOAT_TYPE(b4.x), FLOAT_TYPE((sign &  16) != 0 ? -grid1.x : grid1.x),
38                      fma(FLOAT_TYPE(b4.y), FLOAT_TYPE((sign &  32) != 0 ? -grid1.y : grid1.y),
39                      fma(FLOAT_TYPE(b4.z), FLOAT_TYPE((sign &  64) != 0 ? -grid1.z : grid1.z),
40                      fma(FLOAT_TYPE(b4.w), FLOAT_TYPE((sign7 &  1) != 0 ? -grid1.w : grid1.w),
41                      FLOAT_TYPE(0.0)))))))));
42                temp[j][n] = fma(db, sum, temp[j][n]);
43            }
44        }
45        ibi += num_blocks_per_row;
46    }
47}
48
49void compute_outputs(const uint32_t first_row, const uint32_t num_rows) {
50    uint a_offset, b_offset, d_offset;
51    get_offsets(a_offset, b_offset, d_offset);
52
53    const uint num_blocks_per_row = p.ncols / QUANT_K;
54
55    // 16 threads are used to process each block
56    const uint blocks_per_wg = gl_WorkGroupSize.x/16;
57    const uint tid = gl_LocalInvocationID.x;
58    const uint itid = tid % 16;  // 0...15
59    const uint ix = tid / 16;
60
61    [[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
62        [[unroll]] for (uint i = 0; i < NUM_ROWS; ++i) {
63            temp[j][i] = FLOAT_TYPE(0);
64        }
65    }
66
67    [[unroll]] for (uint i = ix; i < num_blocks_per_row; i += blocks_per_wg)
68        calc_superblock(a_offset, b_offset, itid, i, num_blocks_per_row, first_row, num_rows);
69
70    reduce_result(temp, d_offset, first_row, num_rows, tid);
71}
72
73void main() {
74    const uint first_row = NUM_ROWS * (gl_WorkGroupID.x + gl_NumWorkGroups.x * gl_WorkGroupID.z);
75
76    init_iq_shmem(gl_WorkGroupSize);
77
78    // do NUM_ROWS at a time, unless there aren't enough remaining rows
79    if (first_row + NUM_ROWS <= p.stride_d) {
80        compute_outputs(first_row, NUM_ROWS);
81    } else {
82        if (first_row >= p.stride_d) {
83            return;
84        }
85        compute_outputs(first_row, p.stride_d - first_row);
86    }
87}