1#version 450
 2#extension GL_EXT_shader_explicit_arithmetic_types_int32 : require
 3
 4#include "mul_mat_vec_base.glsl"
 5
 6layout(local_size_x_id = 0, local_size_y = 1, local_size_z = 1) in;
 7
 8FLOAT_TYPE temp[NUM_COLS][NUM_ROWS];
 9
10void calc_superblock(const uint a_offset, const uint b_offset, const uint ib32, const uint i, const uint num_blocks_per_row, const uint first_row, const uint num_rows) {
11    const uint y_idx = i * QUANT_K + 32 * ib32;
12
13    uint ibi = a_offset + first_row * num_blocks_per_row + i;
14    [[unroll]] for (uint n = 0; n < num_rows; ++n) {
15        const float d = float(data_a[ibi].d);
16        const uint scale = (data_a[ibi].scales[ib32/2] >> (4 * (ib32 & 1))) & 0xF;
17        const float dscale = d * (1 + 2 * scale);
18        const uint qh = data_a[ibi].qh[ib32];
19        FLOAT_TYPE sum[NUM_COLS];
20        [[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
21            sum[j] = 0.0;
22        }
23        [[unroll]] for (uint l = 0; l < 4; ++l) {
24            const u8vec2 qs = unpack8(uint32_t(data_a_packed16[ibi].qs[4 * ib32 + l])).xy; // vec4 used due to #12147
25            const uint sign = data_a[ibi].signs[4 * ib32 + l];
26            const vec4 grid0 = vec4(unpack8(iq3s_grid[qs.x | ((qh << (8 - 2*l)) & 0x100)]));
27            const vec4 grid1 = vec4(unpack8(iq3s_grid[qs.y | ((qh << (7 - 2*l)) & 0x100)]));
28
29            [[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
30                const vec4 b0 = vec4(data_b_v4[(j*p.batch_stride_b + b_offset + y_idx) / 4 + 2*l + 0]);
31                const vec4 b4 = vec4(data_b_v4[(j*p.batch_stride_b + b_offset + y_idx) / 4 + 2*l + 1]);
32
33                sum[j] =
34                      fma(FLOAT_TYPE(b0.x), FLOAT_TYPE((sign &   1) != 0 ? -grid0.x : grid0.x),
35                      fma(FLOAT_TYPE(b0.y), FLOAT_TYPE((sign &   2) != 0 ? -grid0.y : grid0.y),
36                      fma(FLOAT_TYPE(b0.z), FLOAT_TYPE((sign &   4) != 0 ? -grid0.z : grid0.z),
37                      fma(FLOAT_TYPE(b0.w), FLOAT_TYPE((sign &   8) != 0 ? -grid0.w : grid0.w),
38                      fma(FLOAT_TYPE(b4.x), FLOAT_TYPE((sign &  16) != 0 ? -grid1.x : grid1.x),
39                      fma(FLOAT_TYPE(b4.y), FLOAT_TYPE((sign &  32) != 0 ? -grid1.y : grid1.y),
40                      fma(FLOAT_TYPE(b4.z), FLOAT_TYPE((sign &  64) != 0 ? -grid1.z : grid1.z),
41                      fma(FLOAT_TYPE(b4.w), FLOAT_TYPE((sign & 128) != 0 ? -grid1.w : grid1.w),
42                      sum[j]))))))));
43            }
44        }
45        [[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
46            temp[j][n] = fma(dscale, sum[j], temp[j][n]);
47        }
48        ibi += num_blocks_per_row;
49    }
50}
51
52void compute_outputs(const uint32_t first_row, const uint32_t num_rows) {
53    uint a_offset, b_offset, d_offset;
54    get_offsets(a_offset, b_offset, d_offset);
55
56    const uint num_blocks_per_row = p.ncols / QUANT_K;
57
58    // 8 threads are used to process each block
59    const uint blocks_per_wg = gl_WorkGroupSize.x/8;
60    const uint tid = gl_LocalInvocationID.x;
61    const uint itid = tid % 8;  // 0...7
62    const uint ix = tid / 8;
63
64    [[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
65        [[unroll]] for (uint i = 0; i < NUM_ROWS; ++i) {
66            temp[j][i] = FLOAT_TYPE(0);
67        }
68    }
69
70    [[unroll]] for (uint i = ix; i < num_blocks_per_row; i += blocks_per_wg)
71        calc_superblock(a_offset, b_offset, itid, i, num_blocks_per_row, first_row, num_rows);
72
73    reduce_result(temp, d_offset, first_row, num_rows, tid);
74}
75
76void main() {
77    const uint first_row = NUM_ROWS * (gl_WorkGroupID.x + gl_NumWorkGroups.x * gl_WorkGroupID.z);
78
79    init_iq_shmem(gl_WorkGroupSize);
80
81    // do NUM_ROWS at a time, unless there aren't enough remaining rows
82    if (first_row + NUM_ROWS <= p.stride_d) {
83        compute_outputs(first_row, NUM_ROWS);
84    } else {
85        if (first_row >= p.stride_d) {
86            return;
87        }
88        compute_outputs(first_row, p.stride_d - first_row);
89    }
90}