1#version 450
 2
 3#include "generic_binary_head.glsl"
 4#include "types.glsl"
 5
 6#extension GL_EXT_control_flow_attributes : enable
 7#extension GL_KHR_shader_subgroup_arithmetic : enable
 8#extension GL_KHR_shader_subgroup_basic : enable
 9
10#define BLOCK_SIZE 128
11
12layout (constant_id = 1) const bool do_multiply = false;
13
14layout(local_size_x = BLOCK_SIZE, local_size_y = 1, local_size_z = 1) in;
15
16layout (binding = 3, std430) readonly buffer PartialsBuf {float partial_sums[];};
17
18shared FLOAT_TYPE sumsh[BLOCK_SIZE];
19
20void main() {
21    const uint ncols     = p.ne00;
22    const uint nrows     = gl_NumWorkGroups.x;
23    const uint nchannels = gl_NumWorkGroups.y;
24
25    const uint row       = 0;
26    const uint channel   = gl_WorkGroupID.y;
27    const uint samp      = gl_WorkGroupID.z;
28    // The work is split across multiple workgroups in the x dimension. Each invocation
29    // processes one element
30    const uint tid       = gl_GlobalInvocationID.x;
31
32    const uint stride_row       = p.nb01;
33    const uint stride_channel   = p.nb02;
34    const uint stride_sample    = p.nb03;
35
36    uint32_t a_offset = samp*stride_sample + channel*stride_channel + row*stride_row + get_aoffset();
37    uint32_t b_offset = src1_idx(0, row, channel, samp) + get_boffset();
38    uint32_t d_offset = ((samp*nchannels + channel)*nrows + row)*ncols + get_doffset();
39
40    FLOAT_TYPE sum = FLOAT_TYPE(0.0f); // partial sum for thread in warp
41
42    uint32_t num_partials = p.param3;
43    for (uint32_t i = gl_SubgroupInvocationID; i < num_partials; i += gl_SubgroupSize) {
44        sum += partial_sums[i];
45    }
46    sum = subgroupAdd(sum);
47
48    uint col = tid;
49    if (col >= ncols) {
50        return;
51    }
52
53    const FLOAT_TYPE mean = sum / FLOAT_TYPE(ncols);
54    const FLOAT_TYPE scale = inversesqrt(mean + FLOAT_TYPE(p.param1));
55
56    if (do_multiply) {
57        if (ncols > p.ne10) {
58            data_d[d_offset + col] = D_TYPE(scale * FLOAT_TYPE(data_a[a_offset + col]) * FLOAT_TYPE(data_b[b_offset + fastmod(col, p.ne10)]));
59        } else {
60            data_d[d_offset + col] = D_TYPE(scale * FLOAT_TYPE(data_a[a_offset + col]) * FLOAT_TYPE(data_b[b_offset + col]));
61        }
62    } else {
63        data_d[d_offset + col] = D_TYPE(scale * FLOAT_TYPE(data_a[a_offset + col]));
64    }
65}