1include_directories(${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR})
 2
 3# server-context containing the core server logic, used by llama-server and CLI
 4
 5set(TARGET server-context)
 6
 7add_library(${TARGET} STATIC
 8    server-task.cpp
 9    server-task.h
10    server-queue.cpp
11    server-queue.h
12    server-common.cpp
13    server-common.h
14    server-context.cpp
15    server-context.h
16)
17
18if (BUILD_SHARED_LIBS)
19    set_target_properties(${TARGET} PROPERTIES POSITION_INDEPENDENT_CODE ON)
20endif()
21
22target_include_directories(${TARGET} PRIVATE ../mtmd)
23target_include_directories(${TARGET} PRIVATE ${CMAKE_SOURCE_DIR})
24target_link_libraries(${TARGET} PUBLIC common mtmd ${CMAKE_THREAD_LIBS_INIT})
25
26
27# llama-server executable
28
29set(TARGET llama-server)
30
31if (NOT LLAMA_HTTPLIB)
32    message(FATAL_ERROR "LLAMA_HTTPLIB is OFF, cannot build llama-server. Hint: to skip building server, set -DLLAMA_BUILD_SERVER=OFF")
33endif()
34
35set(TARGET_SRCS
36    server.cpp
37    server-http.cpp
38    server-http.h
39    server-models.cpp
40    server-models.h
41)
42set(PUBLIC_ASSETS
43    index.html.gz
44    loading.html
45)
46
47foreach(asset ${PUBLIC_ASSETS})
48    set(input "${CMAKE_CURRENT_SOURCE_DIR}/public/${asset}")
49    set(output "${CMAKE_CURRENT_BINARY_DIR}/${asset}.hpp")
50    list(APPEND TARGET_SRCS ${output})
51    add_custom_command(
52        DEPENDS "${input}"
53        OUTPUT "${output}"
54        COMMAND "${CMAKE_COMMAND}" "-DINPUT=${input}" "-DOUTPUT=${output}" -P "${PROJECT_SOURCE_DIR}/scripts/xxd.cmake"
55    )
56    set_source_files_properties(${output} PROPERTIES GENERATED TRUE)
57endforeach()
58
59add_executable(${TARGET} ${TARGET_SRCS})
60install(TARGETS ${TARGET} RUNTIME)
61
62target_include_directories(${TARGET} PRIVATE ../mtmd)
63target_include_directories(${TARGET} PRIVATE ${CMAKE_SOURCE_DIR})
64target_link_libraries(${TARGET} PRIVATE server-context PUBLIC common cpp-httplib ${CMAKE_THREAD_LIBS_INIT})
65
66if (WIN32)
67    TARGET_LINK_LIBRARIES(${TARGET} PRIVATE ws2_32)
68endif()
69
70target_compile_features(${TARGET} PRIVATE cxx_std_17)